Navigation:Home > Content >

CandleColor.mq4

Time: 2013-12-02 | Download file:CandleColor.mq4

/*
CandleColor.mq4
© 2009 Eugene Logunov (lea)
*/
#property copyright "© 2009 Eugene Logunov (lea)"

/***************************************************************************************/

// настройки параметров отображения индикатора
#property indicator_separate_window
#property indicator_minimum -1.25
#property indicator_maximum 1.25
#property indicator_buffers 3
#property indicator_color1 Blue
#property indicator_color2 Red
#property indicator_color3 Green

/***************************************************************************************/

// определения возможных направлений свечей
#define DIRECTION_NONE 0
#define DIRECTION_UP 1
#define DIRECTION_DOWN -1

/***************************************************************************************/

// период средней скользящей от направлений свечей
extern int period=15;

/***************************************************************************************/

// гистограммы направлений свечей
double bufDirHistUp[];
double bufDirHistDown[];
// средняя скользящая по направлениям свечей
double bufDirSoft[];
// буфер для ряда направлений свечей
double bufDir[];

/***************************************************************************************/

// получение направления свечи
double GetCandleDirection(int shift) {
   double diff=Close[shift]-Open[shift];
   if (diff>0.0) {
      return (DIRECTION_UP);
   }
   else if (diff<0.0) {
      return (DIRECTION_DOWN);
   }
   else /*if (diff==0.0)*/ {
      return (DIRECTION_NONE);
   }
}

/***************************************************************************************/

int init() {
   // индикатор использует 1 дополнительный буфер для расчетов
   IndicatorBuffers(4);
   // устанавливаем стили отрисовки для буферов
   SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexStyle(2,DRAW_LINE);
   // привязываем буферы
   SetIndexBuffer(0,bufDirHistUp);
   SetIndexBuffer(1,bufDirHistDown);
   SetIndexBuffer(2,bufDirSoft);
   SetIndexBuffer(3,bufDir);
   return (0);
}

int start() {
   int limit=MathMax(1,MathMin(Bars-1,Bars-IndicatorCounted()+1));
   // определяем направления свечей; разделяем их на 2 гистограммы
   for (int shift=limit;shift>=0;shift--) {
      bufDir[shift]=GetCandleDirection(shift);
      bufDirHistUp[shift]=MathMax(0,bufDir[shift]);
      bufDirHistDown[shift]=MathMin(0,bufDir[shift]);
   }
   limit=MathMax(limit-period,0);
   // расчитываем среднюю скользящую по буферу направлений свечей
   for (shift=limit;shift>=0;shift--) {
      bufDirSoft[shift]=iMAOnArray(bufDir,0,period,0,MODE_SMA,shift);
   }
   return (0);
}

Recommend