Navigation:Home > Content >

TrendStrength_jurik_mtf_alerts_arrows.mq4

Time: 2017-05-20 | Download file:TrendStrength_jurik_mtf_alerts_arrows.mq4

//+------------------------------------------------------------------+ 
//|                                         TrendStrength jurik .mq4 | 
//|                                                                  | 
//|                                        http://www.forextsd.com/  |
//+------------------------------------------------------------------+ 
#property copyright "Copyright © 2010, Forex-TSD.com "
#property link      "http://www.forex-tsd.com/"

#property indicator_separate_window 
#property indicator_buffers 1 
#property indicator_color1 Green
#property indicator_width1 2
#property indicator_level1  -0.40
#property indicator_level2  0.40
#property indicator_levelstyle STYLE_DOT
#property indicator_levelcolor Magenta


extern string TimeFrame        = "Current time frame";
extern int    Price            = 0;
extern int    Phase            = 0;
extern bool   Interpolate      = true;

extern bool   ShowArrows       = true;
extern string ArrowsIdentifier = "tsjurik";
extern color  ArrowUpColor     = Aqua;
extern int    ArrowUpWidth     = 2;
extern color  ArrowDownColor   = Red; 
extern int    ArrowDownWidth   = 2; 
extern double highlevel        = 0.40;
extern double lowlevel         = -0.40;

extern string _                = "alerts settings";
extern bool   alertsOn         = true;
extern bool   alertsOnCurrent  = true;
extern bool   alertsMessage    = true;
extern bool   alertsSound      = false;
extern bool   alertsEmail      = false;



double TS[];
double trend[];
double atrend[];

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
int    timeFrame;



int init() 
  { 
   IndicatorBuffers(3);  
   SetIndexBuffer(0,TS); SetIndexStyle(0, DRAW_LINE); SetIndexDrawBegin(0,2);  SetIndexLabel(0,"TS"); 
   SetIndexBuffer(1,trend);
   SetIndexBuffer(2,atrend); 
   
   indicatorFileName = WindowExpertName();
   calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
   returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
   timeFrame         = stringToTimeFrame(TimeFrame);
   
  IndicatorShortName(timeFrameToString(timeFrame) + " TrendStrength jurik "); 
   
   return(0); 
  } 

int deinit() 
  { 
  if (ShowArrows)
   {
      int compareLength = StringLen(ArrowsIdentifier);
      for (int i=ObjectsTotal(); i>= 0; i--)
      {
      string name = ObjectName(i);
      if (StringSubstr(name,0,compareLength) == ArrowsIdentifier)
       ObjectDelete(name);  
      }
   }

   return(0); 
  } 

int start() 
  { 
   
   double ma0, ma1, ma2, ma3, ma4, ma5, ma6, ma7, ma8, ma9, tmp; 
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars)  { TS[0] = limit+1; return(0); }
         
   if (calculateValue || timeFrame==Period())
   {

   for(i=limit; i>=0; i--)
   {
       tmp=iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i), 5, Phase,i,0);    
   ma1=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),10,Phase,i,10);    
   ma2=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),20,Phase,i,20);    
   ma3=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),30,Phase,i,30);    
   ma4=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),40,Phase,i,40);    
   ma5=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),50,Phase,i,50);    
   ma6=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),60,Phase,i,60);    
   ma7=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),70,Phase,i,70);    
   ma8=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),80,Phase,i,80);    
   ma9=tmp-iSmooth(iMA(NULL,0,1,0,MODE_SMA,Price,i),90,Phase,i,90);            
         
   TS[i]=(ma1+ma2+ma3+ma4+ma5+ma6+ma7+ma8+ma9)/9;
   
   
   
   trend[i] = trend[i+1];
   if(TS[i] <  lowlevel && TS[i+1] >=  lowlevel) trend[i] =  1;  
   if(TS[i] > highlevel && TS[i+1] <= highlevel) trend[i] = -1; 
   
   manageArrow(i);
        
   } 
   
   manageAlerts();
         
   return(0); 
  }
  
  limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
  for(i=limit; i>=0; i--)
  {
  int y = iBarShift(NULL,timeFrame,Time[i]);
  
  TS[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Price,Phase,0,y);
  
  manageArrow(i);
  
  trend[i] = trend[i+1];
  if(TS[i] <  lowlevel && TS[i+1] >=  lowlevel) trend[i] =  1;  
  if(TS[i] > highlevel && TS[i+1] <= highlevel) trend[i] = -1; 
  
  if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
  if (!Interpolate) continue;
   
   
  datetime time = iTime(NULL,timeFrame,y);
  for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
  double factor = 1.0 / n;
  for(int k = 1; k < n; k++)
   
  TS[i+k]  = k*factor*TS[i+n]  + (1.0-k*factor)*TS[i];
  }
   
   manageAlerts();
   return(0);
               
}

void manageArrow(int i)
{
   if (ShowArrows && !calculateValue)
   {
      double dist = iATR(NULL,0,20,i)/2.0;
      ObjectDelete(ArrowsIdentifier+Time[0]);         
            
      //
      //
      //
      //
      //
           
      atrend[i] = atrend[i+1];
      if(TS[i] <  lowlevel && TS[i+1] >=  lowlevel) atrend[i] =  1;  
      if(TS[i] > highlevel && TS[i+1] <= highlevel) atrend[i] = -1; 
         if (atrend[i] !=atrend[i+1])
         {
            string name = ArrowsIdentifier+Time[i];
            if (atrend[i] == 1)
            {
               ObjectCreate(name,OBJ_ARROW,0, Time[i],Low[i]-dist );
                  ObjectSet(name,OBJPROP_ARROWCODE,241);
                  ObjectSet(name,OBJPROP_COLOR,ArrowUpColor);
                  ObjectSet(name,OBJPROP_WIDTH,ArrowUpWidth);
            }
            else
            {
               ObjectCreate(name,OBJ_ARROW,0, Time[i],High[i]+dist );
                  ObjectSet(name,OBJPROP_ARROWCODE,242);
                  ObjectSet(name,OBJPROP_COLOR,ArrowDownColor);
                  ObjectSet(name,OBJPROP_WIDTH,ArrowDownWidth);
            }
         }
   }
}

void manageAlerts()
{
   if (alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] == 1) doAlert(whichBar,"up");
         if (trend[whichBar] ==-1) doAlert(whichBar,"down");
      }         
   }
}   

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," - ",timeFrameToString(timeFrame)+" Trendstrength jurik trend changed to ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol()," Trendstrength jurik "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

  
  
double wrk[][100];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}


string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char = StringGetChar(s, length);
         if((char > 96 && char < 123) || (char > 223 && char < 256))
                     s = StringSetChar(s, length, char - 32);
         else if(char > -33 && char < 0)
                     s = StringSetChar(s, length, char + 224);
   }
   return(s);
}


Recommend